ASP动态网页制作常用错误处理

2007-12-02 02:27:23  来源:网页教学网 站长整理

WebjxCom提示:ASP是非常简单的,以至于许多的开发者不会去思考错误处理。错误处理能够让你的应用程序更加合理。很多用ASP编写的商业网站,大多数都忽略了错误处理。

   ASP是非常简单的,以至于许多的开发者不会去思考错误处理。错误处理能够让你的应用程序更加合理。很多用ASP编写的商业网站,大多数都忽略了错误处理。  

  错误的类型 

  编译错误:这种错误出现一般都是代码的语法问题。因为编译错误而导致辞ASP停止运行。 

  运行错误:这个错误是发生在你准备运行ASP时的。例如:如果你试图给一个变量赋值,但是却超出了该变量允许的范围。 

  逻辑错误:逻辑错误是最难被发现的,这种错误经常是一种结构错误,电脑是发现不了的。这就需要我们彻头彻尾地检查我们的代码。 

  因为编译错误一般是和逻辑错误一起发生的,一般都能显示出来,所以我们担心的就只是运行错误。它都终止ASP的运行,而且给用户丢下一堆很不友好的文字。  

  那么我们要怎样处理运行错误呢!?我们先来看看,ASP唯一提供给我们的错误命令---On Error Resume Next(这里提醒一下初学者,在ASP中只有On Error Resume Next语句,没有On Error Resume Goto语句) 

  如果你不使用On Error Resume Next语句的话,一切运行错误都会发生,这个是致命的,那么就会有一段错误代码“展现”给用户,而且ASP程序也会停止。 

  下面就是一个错误代码:  

Microsoft OLE DB Provider for ODBC Drivers error 80004005  
[Microsoft][ODBC Driver Manager] Data source name not found and no default driver specified  
/test.asp, line 60

   当我们在程序最上面使用On Error Resume Next语句时,所有的错误都会被忽略,程序会自动执行下一条语句。这样程序就会完全执行,出错后用户也不会看到出错信息。但是这样也有不好的地方,那就是如果程序没有按照你想像的执行的话,你就很难找到到底是哪里出了问题,所以你就得在必要的地方对错误进行处理。  

  处理错误

  在ASP中,处理错误的最好的办法就是在程序最底端放上代码来处理错误。推荐在每个ASP程序都使用缓冲区。这样的话,如果错误发生,页面就会停止,页面内容也会被清除,这样用户就不会看到错误信息,对你们的抱怨也就少了!下面是一个例子:  

<% 
'设置buffer为True 
Response.Buffer = True  
'开始错误处理 
On Error Resume Next 
%>  
<%  
'错误处理 
If Err.Number <> 0 Then 
'清除页面 
Response.Clear 
'显示错误信息给用户  
%> 
  <HTML> 
  <HEAD> 
  <TITLE></TITLE> 
  </HEAD> 
  <BODY BGCOLOR="#C0C0C0"> 
  <FONT FACE="ARIAL">An error occurred in the execution of this ASP page<BR> 
  Please report the following information to the support desk<P> 
         <B>Page Error Object</B><BR> 
         错误 Number: <%= Err.Number %><BR> 
         错误信息: <%= Err.Description %><BR>  
         出错文件: <%= Err.Source %><BR> 
         出错行: <%= Err.Line %><BR> 
  </FONT> 
  </BODY> 
  </HTML> 
<%End If%>

  上面的例子首先设置On Error Resume Next ,这样出现错误就不会影响程序的执行。

  错误处理和数据库

  在错误处理中加入数据库的执行是很复杂的。假若我们有一个程序,有很多的命令去向数据库中添加记录,如果insert/update在程序的最底部执行,如果我们前面又错误发生,那就完了!我们就会向数据库中添加了一个错误的信息。因为我们用了On Error Resume Next 一切的错误都被忽略了!即使前面出错,程序依旧会向数据库中添加数据的。

      为避免这种情况,我们就先得做些手脚,正确处理的方法如下:  

If Err.Number = 0 And objConnection.Errors.Count = 0 Then 
'这里才能执行语句,因为没有错误 
Set rstResults = dbData.Execute(txtSql) 
End If   更多高级的处理办法 
  当一个错误发生时,你们也可以显示更多的错误信息。下面是同时处理数据库和页面错误的例子,有了它我们一下就能发现我们程序中的所有错误。
<%  
If Err.Number <> 0 Then 
    Response.Clear 
    Select Case Err.Number 
    Case 8  
        '指定错误的Number 
        '在这里处理自定义错误  
    Case Else 
        '一般错误 
        If IsObject(objConnection) Then 
            If objConnection.Errors.Count > 0 Then 
        %> 
        <B>Database Connection Object</B> 
        <% 
                For intLoop = 0 To objConnection.Errors.Count - 1 %> 
                    Error No: <%= objConnection.Errors(intLoop).Number %><BR> 
                    Description: <%= objConnection.Errors(intLoop).Description %><BR> 
                    Source: <%= objConnection.Errors(intLoop).Source %><BR> 
                    SQLState: <%= objConnection.Errors(intLoop).SQLState %><BR> 
                    NativeError: <%= objConnection.Errors(intLoop).NativeError %><P> 
        <%         Next 
            End If 
        End If 
        If Err.Number <> 0 Then 
            %> 
            <B>Page Error Object</B><BR> 
            Error Number <%= Err.Number %><BR> 
            Error Description <%= Err.Description %><BR>  
            Source <%= Err.Source %><BR> 
            LineNumber <%= Err.Line %><P> 
        <%     
        End If 
    End Select 
End If 
%>


  上面的例子让我们一下了处理了很多在数据库中出现的问题,这个在我们日常编程也是常用的!我们也应该看到那个Select Case 语句,它能让我们来处理特定的错误。

  Redirect 和错误处理

  有一点我们就当注意一下,就是我们常用到的redirect对象,如果一个页面中出现了redirect对象,那么错误处理就失去了意义。所以在转向之前我们还得处理一下,如下:  

  If Err.Number = 0 And objConnection.Errors.Count = 0 Then 
  Response.Clear 
  Response.Redirect URL Here
  End If


  把代码变得更整齐

  为了让代码变得更整齐,首先把错误处理的文件放在一个包含文件中。这样你就可以在任何文件中使用它。这样修改也方便。

  在你程序的最上方加入(当然在语言声明之后)On Error Resume Next语句。 

  在你执行SQL以前进行错误检查。 

  使用redirect以前也要进行错误处理。 

  让你处理错误的包含文件在代码的最上面。
更多